Nanoreseau.net

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
L'utilitaire PHONE8.BAS est un petit programme de discussion entre postes livré avec la disquette système Nanoréseau v3.3. Ce programme illustre le fonctionnement des échanges entre deux postes en BASIC réseau, indépendamment du central. Voici son listing commenté.

<code>
10 ON ERROR GOTO 1000                                                     En cas d'erreur, gestion en 1000
15 CONSOLE0,24
20 CLS
30 INPUT"COPAIN";COPAIN$                                                  Demande le numéro de poste distant
40 OPEN"I",1,"NODE:"+COPAIN$                                              Ouvre un canal en lecture vers ce poste
50 OPEN"O",2,"NODE:"+COPAIN$                                              Ouvre un canal en écriture vers ce poste
60 ON ERROR GOTO 0                                                        Plus de gestion d'erreur
65 CLS
70 X2=0:Y2=13:A2=4:B2=3
80 X=0:Y=0:A=4:B=6
90 COLOR 0,7:LOCATE 0,12:PRINT SPC(40);
91 CONSOLE 0,11:SCREEN A,B,7
92 CONSOLE 13,24:SCREEN A2,B2
93 CONSOLE,,1
100 '
110 '
120 LOCATE X,Y
121 A$=INKEY$                                                             Vérifie si une touche est pressée
130 IF A$="" THEN 220                                                     Non ? Alors on va en 220
140 IF A$=CHR$(1) THEN 500                                                CNT-A pour quitter le programme
141 IF A$=CHR$(13) THEN A$=A$+CHR$(10)
150 CONSOLE 0,11
160 PRINTA$;:X=POS:Y=CSRLIN                                               Affiche le caractère ici
170 PRINT#2,A$;                                                           Et l'envoie au poste distant
180 '
190 '
200 '
210 '
220 A$=INNODE$(1,1)                                                       Vérifie si on a reçu un caractère 
230 IF A$="" THEN GOTO 120 ELSE IF A$=CHR$(1) THEN PRINT#2,A$:CLOSE:END   CNT-A reçu : on quitte
240 CONSOLE 13,24
250 LOCATE X2,Y2:PRINT A$;:X2=POS:Y2=CSRLIN                               Affiche le caractère
260 GOTO 120                                                              Et on reboucle
270 '
500 ' 
510 PRINT#2,CHR$(1)                                                       Envoie caractère de fin (CNT-A)
520 IF INNODE$(1,1)<>CHR$(1) THEN 520                                     Et attend confirmation
530 CONSOLE 0,24,0
540 CLOSE:END                                                             Ferme la liaison et fin
1000 BEEP                                                                 Attend que le poste distant décroche 
1010 CLS:PRINT"Ringing ..."
1020 PLAY"MIDOMI
1030 RESUME
</code>