Nanoreseau.net

This is an old revision of the document!
* NRDOS.MO5 version 3.5
* CMDP2.ASM (Commandes internes, deuxième partie)

************************************************************************************************************
* DRV
* Change le disque courant
************************************************************************************************************
DRV    SET    *
       LDX    TKOFST
       LDB    CMDBUF,X
       CMPB   #'A
       BCS    CDERR

       CMPB   #'J
       BHI    CDERR

       LDB    FNMBF1
       PSHS   B
       LDD    DSKMAP

CDLOOP LSRA
       RORB
       DEC    ,S
       BNE    CDLOOP

       PULS   B
       BCS    CDOK

CDERR  LDB    #128
       JSR    ERRMSG
       BRA    CDEND

CDOK   LDB    FNMBF1
       STB    CDISK

CDEND  RTS

DSKMAP FDB    0

************************************************************************************************************
* ID
* Fixe l'identifiant du poste
************************************************************************************************************
ID     SET    *
       LEAY   FNMBF2,PCR
       LDX    CLPTR,PCR
       LDA    CLTOGO,PCR
       LBSR   SKPSPC
       LBSR   PRSPTH
       STA    CLTOGO,PCR
       STX    CLPTR,PCR
       LDA    #8
       LEAY   IDBUFF,PCR
       LEAX   CSGNDK,PCR
       LBSR   MEMCPY
       LDA    #0           
       STA    CSGNOP,PCR
       LDA    #ID
       STA    CSGNTA,PCR
       LDA    #SYSFIC
       STA    CSGNTR,PCR
       LBSR   XCNSGN
       RTS

************************************************************************************************************
* DATE
* Affiche la date et l'heure
************************************************************************************************************
DATE   SET    *
       LDA    #0           
       STA    CSGNOP,PCR
       LDA    #DATE
       STA    CSGNTA,PCR
       LDA    #SYSFIC
       STA    CSGNTR,PCR
       LBSR   XCNSGN
       BNE    DATEND

       LEAX   DATEST,PCR
       LBSR   DSPSTR
       LEAX   CRBUFF+2,PC
       BSR    D3NBS
       LEAX   TIMEST,PCR
       LBSR   DSPSTR
       LEAX   CRBUFF+5,PC
       BSR    D3NBS
DATEND RTS

************************************************************************************************************
* D3NBS
* Affiche trois nombres entiers 8 bits séparés par des espaces
************************************************************************************************************
D3NBS  SET    *
       LDB    #3
       PSHS   B

D3LOOP:
       LDB    ,X+
       PSHS   X
       LBSR   DINT
       PULS   X
       LBSR   DSPACE
       DEC    ,S
       BNE    D3LOOP

       PULS   PC,B

DATEST FCS    /DATE  : /
TIMEST FCS    / - HEURE : /
Retourner à la liste des fichiers