cmdp4.asm
This is an old revision of the document!
Retourner à la liste des fichiers
* NRDOS.MO5 version 3.5
* CMDP4.ASM (Commandes internes, quatrième partie)
************************************************************************************************************
* CD
* Exécute la commande CD.
************************************************************************************************************
CD SET *
CLR CSGDST ; Central
CLR CSGNPG ; Page 0
LDB #SYSFIC
STB CSGNTR
LDB CDISK
STB CSGNDK
LDX CLPTR
LDA CLTOGO
JSR SKPSPC
BEQ CDGO01
CMPA #2 ; Longueur 2 ?
BNE CDPATH
LDB 1,X
CMPB #COLON
BNE CDPATH
LDB ,X
SUBB #AROB ; Calcule le numéro de disque
STB CSGNDK ; Change le disque courant
CDGO01 LDX #CDTBUF
STX CSGNAD
LDX #64
STX CSGNSZ
LDA #GETDIR
STA CSGNTA
JSR XCNSGN ; Récupère le répertoire courant sur le nouveau disque
BNE CDRTS
LDB CSGNDK ; Affiche le nouveau chemin
ADDB #AROB
JSR PCHAR
LDB #COLON
JSR PCHAR
LDX #CDTBUF
JSR DSPSTR
BRA CDRTS
CDPATH CLR A,X
CMPA #2
BCS CDGO02
LDB 1,X
CMPB #COLON
BNE CDGO02
LDB ,X
SUBB #AROB ; Calcule le numéro de disque
STB CSGNDK
DECA
DECA
LEAX 2,X
CDGO02 EXG A,B
INCB
CLRA
STD CSGNSZ
STX CSGNAD
LDA #SETDIR
STA CSGNTA
JSR XCNSGN
CDRTS RTS
CDTBUF RMB 64
cmdp4.asm.1767006419.txt.gz · Last modified: by fool-duplex